Audiosuite Render key shortcut

[:Rob:]

Is there a shortcut for the software button "Render" in Audiosuite?
Google it do not bring back meaningful results. Any way to assign it to a hardware key?
Thanks!

[albee1952]

None that I am aware of. I just mouse-click on the render button

[Oliver M]

Originally Posted by :Rob:

Is there a shortcut for the software button "Render" in Audiosuite?
Google it do not bring back meaningful results. Any way to assign it to a hardware key?
Thanks!

There is none. However there a several workarounds, are you on Mac or Windows?


Oliver

[shtepy]

I use Quick Keys on a mac and program a mouse click on the Render Button. I leave the Audiosuite window open, it can't be moved or you'll have to reprogram the Quick Key command. I also create a Window configuration in case the Audiosite window gets closed or moved.

[Goombot]

This is a question to an old post... so if you leave the audio suite window in the exact same spot (like recalling it with a Window Configuration) you can program it with Quickeys? Is that what you're saying?

[Oliver M]

Originally Posted by shtepy

I use Quick Keys on a mac and program a mouse click on the Render Button. I leave the Audiosuite window open, it can't be moved or you'll have to reprogram the Quick Key command. I also create a Window configuration in case the Audiosite window gets closed or moved.

You can avoid that by using AppleScript. The window location doesn't matter.

Here is the code to click the Render button in an AudioSuite window for Pro Tools versions 10.3 to 12.4.

set returnValue to missing value

try
	if ptVersionCheck("12.2") then
		activate application "Pro Tools"
		tell application "System Events"
			tell process "Pro Tools"
				tell (1st window whose name contains "Audio Suite") to click button "Render" -- Render button
			end tell
		end tell
		
	else if ptVersionCheck("11.1") then
		activate application "Pro Tools"
		tell application "System Events"
			tell process "Pro Tools"
				tell (1st window whose name contains "Audio Suite") to click button "process" -- Render button
			end tell
		end tell
		
	else if ptVersionCheck("10.3") then
		activate application "Pro Tools"
		tell application "System Events"
			tell process "Pro Tools"
				tell (1st window whose name contains "AudioSuite") to click button "process" -- Process button
			end tell
		end tell
		
	else
		-- Display error message
		tell application "Pro Tools"
			activate
			display dialog "This action requires Pro Tools 10.3 or higher." giving up after 10 with title "Incompatible Pro Tools Version" buttons {"Cancel"} default button "Cancel"
		end tell
	end if
	
on error
	return returnValue
end try

on ptVersionCheck(referenceVersion)
	set proToolsVersion to version of application "Pro Tools"
	considering numeric strings
		return (proToolsVersion as text) is greater than or equal to referenceVersion
	end considering
end ptVersionCheck

Save this code into a new Apple Script Editor document or use it in QuicKeys.

[Goombot]

Wow. Thank you for this. What else do I need to do in order to get it to work? I'm a bit unfamiliar with working with AppleScripts although I know a little bit. I've opened the Script Editor, saved it as a script. I have it in my dropdown menu now. Once I open ProTools, I just created a quick test session. I created one track, imported one sound, selected the clip, opened the Gain plug in and ran the script and nothing happened. Can you let me know what I might be missing or what I might be doing wrong? Thank you. I really appreciated this. chris

[Oliver M]

Originally Posted by Goombot

Wow. Thank you for this. What else do I need to do in order to get it to work? I'm a bit unfamiliar with working with AppleScripts although I know a little bit. I've opened the Script Editor, saved it as a script. I have it in my dropdown menu now. Once I open ProTools, I just created a quick test session. I created one track, imported one sound, selected the clip, opened the Gain plug in and ran the script and nothing happened. Can you let me know what I might be missing or what I might be doing wrong? Thank you. I really appreciated this. chris

The best way of using AppleScripts is to use FastScripts, you can assign shortcuts to each script and they override existing shortcuts of the app you run them in.
Its free for up to 10 scripts.

As for the code not working, it could be that Apple Script Editor is not switching fast enough to Pro Tools.

Add this in front of the code (right at the top):

activate application "Pro Tools"
delay 0.1

This should be obsolete if you trigger the script from FastScripts.

[Goombot]

ok I'll try it and get back. Thank you.

[Oliver M]

Originally Posted by Goombot

ok I'll try it and get back. Thank you.

You can send me a private message and we'll figure it out and continue this conversation via E-Mail.
Once we know what the problem was we can update this thread accordingly.